PDL::ParallelCPU - Man Page

PDL has support for splitting up numerical processing between multiple parallel processor threads (or pthreads) using the set_autopthread_targ and set_autopthread_size functions. This can improve processing performance (by greater than 2-4X in most cases) by taking advantage of multi-core and/or multi-processor machines.

As of 2.059, "online_cpus" in PDL::Core is used to set the number of threads used if PDL_AUTOPTHREAD_TARG is not set.

  use PDL;

  # Set target of 4 parallel pthreads to create, with a lower limit of
  #  5Meg elements for splitting processing into parallel pthreads.
  set_autopthread_targ(4);
  set_autopthread_size(5);

  $x = zeroes(5000,5000); # Create 25Meg element array

  $y = $x + 5; # Processing will be split up into multiple pthreads

  # Get the actual number of pthreads for the last
  #  processing operation.
  $actualPthreads = get_autopthread_actual();

  # Or compare these to see CPU usage (first one only 1 pthread, second one 10)
  # in the PDL shell:
  $x = ones(10,1000,10000); set_autopthread_targ(1); $y = sin($x)*cos($x); p get_autopthread_actual;
  $x = ones(10,1000,10000); set_autopthread_targ(10); $y = sin($x)*cos($x); p get_autopthread_actual;

To reduce the confusion that existed in PDL before 2.075, this document uses pthreading to refer to processor multi-threading, which is the use of multiple processor threads to split up numerical processing into parallel operations.

This is a brief listing and description of the PDL pthreading functions, see the PDL::Core docs for detailed information.

set_autopthread_targ

Set the target number of processor-threads (pthreads) for multi-threaded processing. Setting auto_pthread_targ to 0 means that no pthreading will occur.

See PDL::Core for details.

set_autopthread_size

Set the minimum size (in Meg-elements or 2**20 elements) of the largest PDL involved in a function where auto-pthreading will be performed. For small PDLs, it probably isn't worth starting multiple pthreads, so this function is used to define a minimum threshold where auto-pthreading won't be attempted.

See PDL::Core for details.

get_autopthread_actual

Get the actual number of pthreads executed for the last pdl processing function.

See PDL::get_autopthread_actual for details.

PDL pthreading can be globally turned on, without modifying existing code by setting environment variables PDL_AUTOPTHREAD_TARG and PDL_AUTOPTHREAD_SIZE before running a PDL script. These environment variables are checked when PDL starts up and calls to set_autopthread_targ and set_autopthread_size functions made with the environment variable's values.

For example, if the environment var PDL_AUTOPTHREAD_TARG is set to 3, and PDL_AUTOPTHREAD_SIZE is set to 10, then any pdl script will run as if the following lines were at the top of the file:

 set_autopthread_targ(3);
 set_autopthread_size(10);

The auto-pthreading process works by analyzing broadcast array dimensions in PDL operations (those above the operation's "signature" dimensions) and splitting up processing according to those and the desired number of pthreads (i.e. the pthread target or pthread_targ). The offsets, increments, and dimension-sizes (in case the whole dimension does not divide neatly by the number of pthreads) that PDL uses to step thru the data in memory are modified for each pthread so each one sees a different set of data when performing processing.

Example

 $x = sequence(20,4,3); # Small 3-D Array, size 20,4,3

 # Setup auto-pthreading:
 set_autopthread_targ(2); # Target of 2 pthreads
 set_autopthread_size(0); # Zero so that the small PDLs in this example will be pthreaded

 # This will be split up into 2 pthreads
 $c = maximum($x);

For the above example, the maximum function has a signature of (a(n); [o]c()), which means that the first dimension of $x (size 20) is a Core dimension of the maximum function. The other dimensions of $x (size 4,3) are broadcast dimensions (i.e. will be broadcasted-over in the maximum function.

The auto-pthreading algorithm examines the broadcasted dims of size (4,3) and picks the 4 dimension, since it is evenly divisible by the autopthread_targ of 2. The processing of the maximum function is then split into two pthreads on the size-4 dimension, with dim indexes 0,2 processed by one pthread
and dim indexes 1,3 processed by the other pthread.

Copyright 2011 John Cerney. You can distribute and/or modify this document under the same terms as the current Perl license.

See: <http://dev.perl.org/licenses/>